#!../gtkscript
REM ------------------------------------------------------------------
REM timer program
REM Ported from the newLISP version by PvE.
REM ------------------------------------------------------------------
 
gtk_server_cfg("cfg=../../gtk-server.cfg")

gtk_init(NULL, NULL)
win$ = gtk_window_new(0)
gtk_window_set_title(win$, CHR$(34) + "A different time(r)" + CHR$(34))
gtk_widget_set_size_request(win$, 240, 32)
gtk_window_set_resizable(win$, 0)
gtk_window_set_position(win$, 1)

REM Use new async functionality
gtk_server_connect(win$, "show", "win")
gtk_server_timeout(1000, win$, "show")
 
tbl$ = gtk_table_new(100, 100, 1)
gtk_container_add(win$, tbl$)

pb1$ = gtk_progress_bar_new()
gtk_table_attach_defaults(tbl$, pb1$, 1, 100, 1, 10)

pb2$ = gtk_progress_bar_new()
gtk_table_attach_defaults(tbl$, pb2$, 1, 100, 11, 20)

pb3$ = gtk_progress_bar_new()
gtk_table_attach_defaults(tbl$, pb3$, 1, 100, 21, 30)

gtk_widget_show_all(win$)

DO
    gtk_progress_bar_set_fraction(pb1$, VAL(MID$(TIME$, 1, 2))/24)
    gtk_progress_bar_set_fraction(pb2$, VAL(MID$(TIME$, 4, 2))/60)
    gtk_progress_bar_set_fraction(pb3$, VAL(MID$(TIME$, 7, 2))/60)

    event$ = gtk_server_callback("wait")

UNTIL event$ = win$

gtk_exit(0)
END